不會分組匯總，還敢說自己懂Excel？3種方法教你搞定數據整理！

點擊藍字關注【秋葉 Excel】

發送【7】

免費領 1000+篇 Excel 精選教程！

本文作者：小爽

本文編輯：竺蘭

大家好，這里是秋葉編輯部~

在生活中，我們有時會對每天所購買的產品做一個簡單的記錄。

由于記錄的是一維表，當要進行數據分析的時候，我們要對數據進行匯總操作。

如下圖，我想要知道自己每天購買的商品有哪些，對應的匯總有多少，每天都花了多少錢。

所以，問題又來了，如何將左圖轉換為右圖呢？

看到這種問題，我們的第一反應應該就是使用函數了

分步函數做法

從左表到右表一共三列，那我們就一列列來做。

▋購買日期

由于我們是基于購買日期進行匯總，所以我們對購買日期進行去重操作。

Unique 函數就是用來去重的。

在 E2 單元格中輸入函數公式：

=UNIQUE($C$2:$C$13)

▋購買總金額

基于日期按條件進行判斷，再對對應的金額進行求和匯總。

抓住關鍵字，條件+求和。

我們不難想到 Sumif 函數（Sum 求和+IF 條件）。

Sumif 函數語法規則如下：

=SUMIF(條件區域,條件,求和區域)

在 G2 單元格中，輸入以下函數公式，并下拉填充：

=SUMIF($C$2:$C$13,E2,$B$2:$B$13)

▋購買明細

先梳理一下思路步驟。

以 2025/7/1 日期為例

? 基于 2025/7/1，對數據源按照日期進行篩選。

Filter 函數語法規則：

=FILTER(數組,包括,[是否包含空])

如下圖所示：

=FILTER($A$2:$B$13,$C$2:$C$13=$E$10)

? 將篩選后的產品名稱進行分組求和匯總。

Groupby 函數語法規則：

=GROUPBY(行字段，值區域,匯總方式,[是否包含標頭],[是否顯示總計],[排序方式],[篩選區域],[相關方式])

如下圖所示：

=GROUPBY(F12:F14,G12:G14,SUM,,0)

? 利用合并函數對數據進行合并。

Textjoin函數語法規則：

=TEXTJOIN(分隔符，是否忽略空值,文本1,文本2....)

觀察數據，我們可以發現分隔符為{"",","}。

對應函數公式，如下圖所示：

=TEXTJOIN({"",","},,F16#)

接下來，我們就來整合上面函數。

如下圖，輸入公式并下拉填充：

=LET(data,FILTER($A$2:$B$13,$C$2:$C$13=E2),gy_data,GROUPBY(CHOOSECOLS(data,1),CHOOSECOLS(data,2),SUM,,0),TEXTJOIN({"",","},,gy_data))

其中，涉及函數簡單介紹。

Let 函數

Let 函數是一個自定義函數，用于在公式中定義和使用變量。

使用 Let 函數的好處是，定義變量后方便后續重復調用，這也使得函數公式變得簡潔直觀。

有點類似名稱管理器，不過使用函數更加靈活。

Let 函數語法規則如下：

=LET(名稱1,名稱值1,計算或名稱2,...)

Choosecols 函數

Choosecols 函數能夠取指定區域的第n列。

Choosecols 函數的語法規則如下：

=CHOOSECOLS(數組,列數1,[列數2...])

明白了所需的函數，函數公式就不難理解了。

=LET(
    data,FILTER($A$2:$B$13,$C$2:$C$13=E2),
     //對2025/7/1日期進行篩選，獲取篩選后的產品名稱和數量，數據表。

    gy_data,GROUPBY(CHOOSECOLS(data,1),CHOOSECOLS(data,2),SUM,,0),
     //取data數據第一列也就是產品名稱進行分組，取data第二列也就是數量進行求和。 
    
    TEXTJOIN({"",","},,gy_data)
     //對分組后匯總的數據，進行合并。行方向分隔符為空""，列方向分隔符為逗號。
)

上面我們是函數分步做的，如果想要函數公式一步到位呢？

接下來一起看看。

函數一步到位

我們先來看看具體做法。

輸入如下函數公式：

=LET(
   g,GROUPBY(CHOOSECOLS(A2:C13,3,1),B2:B13,SUM,,0),
   GROUPBY(
      CHOOSECOLS(g,1),      
      HSTACK(CHOOSECOLS(g,2)&CHOOSECOLS(g,3),CHOOSECOLS(g,3)),     
      VSTACK(HSTACK(ARRAYTOTEXT,SUM),{"購買明細","購買總金額"}),,0)
 )

其中，涉及函數簡單介紹。

Hstack 函數

Hstack 函數可以將數組按照橫向拼接。

=HSTACK(數組1,數組2...)

Vstack 函數

Vstack 函數可以將數組按照縱向拼接。

=VSTACK(數組1,數組2...)

明白前面分步思路，理解這個函數公式也簡單。

? 先對日期和產品名稱進行分組，變量定義為 g。

? 對變量 g 的表，進行按日期分組匯總。

GROUPBY(
     CHOOSECOLS(g,1),
     //取g的第一列，也就是日期列
     
     HSTACK(CHOOSECOLS(g,2)&CHOOSECOLS(g,3),CHOOSECOLS(g,3)),
     //取產品名稱列和購買金額列，橫向拼接作為值區域
     
     VSTACK(HSTACK(ARRAYTOTEXT,SUM),{"購買明細","購買總金額"}),,0)
     //匯總方式

好了，到這里，我們的函數方法就介紹完了。

現在是 AI 時代，我們也來看看它給出的解法，這里我使用 WPS 的靈犀 AI。

靈犀 AI

前面我們基于思考，利用函數解決了問題。

那利用 AI 去解決問題，

Q：最關鍵的是什么?

A：就是你解決問題的思考步驟，要跟 AI 說。

我將圖片上傳給靈犀 AI。

輸入對應的指令：文件信息+要求步驟+整理過程+解決方法

最后靈犀 AI 基于我的思路生成 VBA 代碼。

雖然代碼比較長，但是也解決了問題。

最后的話

本文講解的是基于數據源，進行匯總分析的函數和 AI 解法：

?分步函數公式，基于一列列拆解完成結果。

① Unique 函數，對購買日期進行去重；

② Sumif 函數，對購買日期篩選后求和；

③ Filter+Groupby+Textjoin，篩選分組合并，對信息進行整合。

?一步函數公式，兩次分組獲取結果。

① Groupby，購買日期+產品名稱進行分組；

② 基于上一層分組數據，進行購買日期分組，最后利用 Function 匯總參數，得到結果。

? 要利用 AI 解決問題，關鍵在于思路，不同思路，AI 對應出來的解決方案不同。

工具會變，但是我們處理思路不會變的，無論是 Excel 還是 AI 都一樣。

如果你也想掌握 AI 新工具，希望能盡快上手……

那我推薦你加入《秋葉 AI 智能辦公 3 天實戰營》，秋葉金牌講師教你學會包括飛書多維表格在內的4 大字節工具（豆包、即夢、Coze），帶你快速掌握新工具，提高個人核心競爭力。

《秋葉 AI 智能辦公 3 天實戰營》

課程原價 99 元

現在僅需 0 元！

秋葉實戰派老師直播授課

專業助教隨時答疑

多種 AI 工具教學

名額有限，立即掃碼預約上課

添加微信即可進群上課

隨課免費領取：

6 套飛書多維表格模板

AI 寫真主題提示詞手冊

50+ 秋葉 AI 智能體工具集